新しい機能を追加するなんて、簡単にできるのかなぁ？まずは、前回保存したファイルを開きます。Turbo Delphiを起動して、画面中央の「ホームページ」で「Drawing.bdsproj」を選択。もし一覧に表示されていなければ、ツールバーの[プロジェクトを開く(Ctrl+F11)]ボタンをクリックします。「プロジェクトを開く」ダイアログボックスから「Drawing.bdsproj」を探します。今回追加したい機能は、ペンの太さと、色を変えること。ペンの太さは、ボタンで細書きと太書きを切り替えられるようにして、ペンの色は、ボタンか何かで細かく色を変更できると分かりやすくていいね。

では、やってみますね。画面中央を「FormDrawing」のフォームデザインの画面に変更します。画面右下のツールパレット「Standard」カテゴリから「TPanel」コンポーネントを探します。見つかったら、クリックしてフォーム上をクリックします。

プロパティを設定します。TPanelコンポーネントを選択していることを確認して、画面左下のオブジェクトインスペクタ「プロパティ」ページで「レイアウト」カテゴリの「Align」プロパティを探します。見つかったらAlignプロパティを「alLeft」に変更します。

なんか変な感じがするけど、なんでだろう？

Hide image

図01 TPanelの配置

では、指示に従って親子関係を変更します。構造ペインで「Panel1」を「frmMain」の上にドラッグします。うまく変更できたら、プロパティを変更します。幅の調整はフォームデザインで青いサイズ変更ハンドルをドラッグして調整するか、画面左下のオブジェクトインスペクタ、プロパティページで「レイアウト」カテゴリの「Width」プロパティに「70」と入力します。次に「ローカライズ対象」カテゴリの「Caption」プロパティに入力されている文字を削除します。

    TSpeedButtonのグループ化とコンポーネントの複数選択

    Penプロパティの設定

procedure TfrmMain.pbxDrawMouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
var
  w: Integer;
begin

  if GetKeyState(VK_LBUTTON) < 0 then
  begin
    if sbtnHoso.Down then
      w := 5
    else
      w := 20;

    pbxDraw.Canvas.Pen.Mode  := pmCopy;
    pbxDraw.Canvas.Pen.Width := w;
    pbxDraw.Canvas.Pen.Color := clBlack;
    pbxDraw.Canvas.MoveTo(preX, preY);
    pbxDraw.Canvas.LineTo(X, Y);

    bmpBuf.Canvas.Pen.Mode  := pmCopy;
    bmpBuf.Canvas.Pen.Width := w;
    bmpBuf.Canvas.Pen.Color := clBlack;
    bmpBuf.Canvas.MoveTo(preX, preY);
    bmpBuf.Canvas.LineTo(X, Y);
  end;

  preX := X;
  preY := Y;

end;

    ダイアログボックスの使い方

shpColorコンポーネントをクリックしたとき、ダイアログボックスを出すようにコードを記述したいんですけど、OnClickイベントがありませんね。

難しそうなことができるのに、コードは単純なのね。イベントハンドラを作成します。shpColorシェープコンポーネントを選択してオブジェクトインスペクタ、イベントページの「入力」カテゴリで「OnMouseUp」を探してダブルクリックします。以下のコードの太字部分を追加します。

procedure TfrmMain.shpColorMouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  if ColorDialog1.Execute then
    shpColor.Brush.Color := ColorDialog1.Color;
end;

次にペンに色指定します。今回もピクチャーボックスの「OnMouseMove」で設定します。ペンの太さと同じく変数を用意します。変数名は「c」、型名は「TColor」とします。型がそろわないと代入できないもんね。sbtnHosoボタンがへこんでいるかどうかのIf文(if sbtnHoso.Down then …)のすぐ下で、c変数にshpColorの「Brush.Color」プロパティの値を代入します。

ペイントボックスコンポーネントとビットマップオブジェクトの「Pen.Color」プロパティに「clBlack」を代入している部分2箇所で、「c」変数を代入するよう書き換えます。太字の部分を追加変更します。

unit FormDrawing;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, XPMan, Buttons;

type
  TfrmMain = class(TForm)
    sbxDraw: TScrollBox;
    XPManifest1: TXPManifest;
    Panel1: TPanel;
    pbxDraw: TPaintBox;
    sbtnHoso: TSpeedButton;
    sbtnFuto: TSpeedButton;
    shpColor: TShape;
    ColorDialog1: TColorDialog;
    procedure pbxDrawMouseMove(Sender: TObject; Shift: TShiftState; X,
      Y: Integer);
    procedure pbxDrawMouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure FormCreate(Sender: TObject);
    procedure pbxDrawPaint(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure shpColorMouseUp(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
  private
    { Private 宣言 }
    preX: Integer;
    preY: Integer;
    bmpBuf: TBitmap;
  public
    { Public 宣言 }
  end;

var
  frmMain: TfrmMain;

implementation

{$R *.dfm}

procedure TfrmMain.FormCreate(Sender: TObject);
begin
  preX := -1;
  preY := -1;
  bmpBuf := TBitmap.Create;
  bmpBuf.PixelFormat := pf32bit;
  bmpBuf.SetSize(640, 480);
end;

procedure TfrmMain.FormDestroy(Sender: TObject);
begin
//  ReportMemoryLeaksOnShutdown := True;

  if Assigned(bmpBuf) then
  begin
    bmpBuf.FreeImage;
    FreeAndNil(bmpBuf);
  end;
end;

procedure TfrmMain.pbxDrawMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  if GetKeyState(VK_LBUTTON) < 0 then
  begin
    pbxDrawMouseMove(Sender, Shift, X, Y);
  end;
end;

procedure TfrmMain.pbxDrawMouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
var
  w: Integer;
  c: TColor;
begin

  if GetKeyState(VK_LBUTTON) < 0 then
  begin
    if sbtnHoso.Down then
      w := 5
    else
      w := 20;

    c := shpColor.Brush.Color;

    pbxDraw.Canvas.Pen.Mode  := pmCopy;
    pbxDraw.Canvas.Pen.Width := w;
    pbxDraw.Canvas.Pen.Color := c;
    pbxDraw.Canvas.MoveTo(preX, preY);
    pbxDraw.Canvas.LineTo(X, Y);

    bmpBuf.Canvas.Pen.Mode  := pmCopy;
    bmpBuf.Canvas.Pen.Width := w;
    bmpBuf.Canvas.Pen.Color := c;
    bmpBuf.Canvas.MoveTo(preX, preY);
    bmpBuf.Canvas.LineTo(X, Y);
  end;

  preX := X;
  preY := Y;

end;

procedure TfrmMain.pbxDrawPaint(Sender: TObject);
begin
  pbxDraw.Canvas.CopyMode := cmSrcCopy;
  pbxDraw.Canvas.Draw(0, 0, bmpBuf);
end;

procedure TfrmMain.shpColorMouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  if ColorDialog1.Execute then
    shpColor.Brush.Color := ColorDialog1.Color;
end;

end.

変更できたら、保存して実行してみます。shpColorシェープコンポーネントをクリックします。表示したダイアログボックスで、色を黒以外に設定して[OK]ボタンをクリックします。ペイントボックスで絵を描きます。

Hide image

05完成図

色の追加ボタンで、独自に追加した色も使うことができます。